正在加载文档
回收相关命令
<!-- mindoc:slug=aa-1hglonrhe3u4g -->
#### 检测包裹指定极品属性装备命令一：
>CHECKITEMWITEMVALUE 参数1 参数2 参数3 参数4 参数5 参数6 参数7
#### 参数说明：
|位置|说明|备注|
|:----|:---|:---
|参数1 |装备名字|该参数为*为检测包裹所有物品，支持用|分割可同时检测多个装备名字|
|参数2 |属性分类|0:普通属性 / 1:元素属性 / 2:装备名字颜色 / 3:装备加星数量|
|参数3 |属性位置|普通属性分为0-6 / 元素属性分为1-19 (如果该参数为-1则表示计算该属性分类值的总和)(-2表示 0-4属性中最大的值)|
|参数4 |检测符|< 、 > 、=|
|参数5 | 数值 ||
|参数6 |单次使用TakeItemWitemValue收走的最大数量|参数为0则不限制|
|参数7 |是否清理缓存|0:清理 / -1:不清理 详情看测试脚本(测试五、测试六、测试七)|
#### 检测包裹指定属性物品命令一：
>CHECKFILTERITEMS 参数1 参数2 参数3 参数4 参数5
#### 参数说明：
|位置|说明|备注|
|:----|:---|:---
|参数1 |检测条件| DB中属性名|
|参数2 |检测符|< 、 > 、=|
|参数3 |检测数值 ||
|参数4 |返回数量 ||
|参数5 |是否清理缓存|0:清理 / -1:不清理 详情看测试脚本|
#### 收取满足条件极品属性装备命令：
>TAKEITEMWITEMVALUE 参数1 参数2
#### 参数说明：
|位置|说明|备注|
|:----|:---|:---
|参数1 |指定变量获取本次收走的装备数量||
|参数2 |本次收走最大数量|参数为0或忽略则无限制|
#### 示例:
```
[@测试A]
#IF
CheckFilterItems STDMODE = 4 P1
CheckFilterItems SHAPE = 0 P2
#ACT
SENDMSG 5 你包裹stdmode为4的技能书有<$STR(P1)>本
SENDMSG 5 你包裹(stdmode为4)且(SHAPE为0)的战士技能书有<$STR(P2)>本
break
[@测试B]
#IF
CheckItemWitemValue * 0 -1 > 0 0 ;检测包裹极品属性总和大于0的物品
CheckFilterItems UPGRADECOUNT < 1 P1 -1 ;满足极品条件且星星数量小于1
#ACT
SENDMSG 5 满足以上双重条件的物品数量为:<$STR(P1)>
TakeItemWitemValue N1 5
SENDMSG 5 收走满足条件以上物品，如果物品数量大于5个，只收走5个。
break
```
```
[@测试一]
#IF
CheckItemWitemValue * 0 -1 > 0 0 ;检测包裹 “极品属性大于0” 的所有装备
#ACT
TakeItemWitemValue N1 ;收走满足条件的物品，收走的数量保存在N1变量
SENDMSG 5 收走了<$STR(N1)>件装备
WHILE N1 > 0 ;通过循环判断 N1大于0 (N1是回收装备数量)
DEC N1 1 ;每次循环将N1减1
give 金币 1000 ;每次循环增加1000金币 (回收了多少件装备就通过循环给多少次金币)
SENDMSG 5 金币增加+1000
END
```
```
[@测试二]
#IF
CheckItemWitemValue 圣战头盔|圣战项链|圣战手镯|圣战戒指 1 -1 > 0 0 ;检测包裹指定圣战系列 “元素属性大于0” 的装备
#ACT
TakeItemWitemValue N2 ;收走满足条件的物品，收走的数量保存在N2变量
SENDMSG 5 你本次收走了<$STR(N2)>件装备
break
```
```
[@测试三]
#IF
CheckItemWitemValue * 2 0 = 253 0 ;检测包裹 “物品名字颜色等于253” 的所有装备
#ACT
TakeItemWitemValue N3 ;收走满足条件的物品，收走的数量保存在N3变量
SENDMSG 5 你本次收走了<$STR(N3)>件装备
break
```
```
[@测试四]
#IF
CheckItemWitemValue * 3 0 > 0 0 ;检测包裹 “装备星星数大于0” 的所有装备
#ACT
TakeItemWitemValue N4 ;收走满足条件的物品，收走的数量保存在N4变量
SENDMSG 5 你本次收走了<$STR(N4)>件装备
break
```
```
[@测试五]
#IF
CheckItemWitemValue 圣战戒指 0 -1 = 0 0 ;检测包裹 “没有极品属性” 的所有圣战戒指
CheckItemWitemValue 法神戒指 0 -1 = 0 0 -1 ;检测包裹 “没有极品属性” 的所有法神戒指
CheckItemWitemValue 天尊戒指 0 -1 = 0 0 -1 ;检测包裹 “没有极品属性” 的所有天尊戒指
#ACT
TakeItemWitemValue N5 ;收走满足条件的物品，会收走【圣战戒指、法神戒指、天尊戒指】所有装备
SENDMSG 5 你本次收走了<$STR(N5)>件装备
break
```
```
[@测试六]
#IF
CheckItemWitemValue 圣战戒指 0 -1 = 0 0 ;检测包裹 “没有极品属性” 的所有圣战戒指
CheckItemWitemValue 法神戒指 0 -1 = 0 8 -1 ;检测包裹 “没有极品属性” 的所有法神戒指，注意这里最大收走数量为8
#ACT
TakeItemWitemValue N6 ;如果包裹有10个圣战戒指，那么本次只收走10个圣战戒指，法神戒指则不收走，因为最大收走数量为8
SENDMSG 5 你本次收走了<$STR(N6)>件装备
break
```
```
[@测试七]
#IF
CheckItemWitemValue 圣战戒指 0 -1 = 0 0 ;检测包裹 “没有极品属性” 的所有圣战戒指
CheckItemWitemValue 法神戒指 0 -1 = 0 8 -1 ;检测包裹 “没有极品属性” 的所有法神戒指，注意这里最大收走数量为8
CheckItemWitemValue 天尊戒指 0 -1 = 0 0 -1 ;检测包裹 “没有极品属性” 的所有天尊戒指
#ACT
TakeItemWitemValue N7 ;如果包裹有5个圣战戒指、5个法神戒指、5个天尊戒指，那么本次只收走5个圣战戒指 + 3个法神戒指 + 5个天尊戒指
SENDMSG 5 你本次收走了<$STR(N7)>件装备
break
```
